// ********************************************************************************************
// Das Heilige Wasser
// ==================
// Der Spieler muß eine Phiole Heiliges Wasser besorgen und zum Auftraggeber zurückbringen.                
// ********************************************************************************************
INSTANCE Mis_HolyWater(C_Mission)
{
   name			= "Das Heilige Wasser";
   global		= 1;			// Globale (TRUE) Mission oder Perönliche (FALSE)
   duration		= 1;			// = 1 Tageszeit

   conditions 	= Mis_HolyWater_Conditions;
   criteria   	= Mis_HolyWater_Criteria;
   offer		= Mis_HolyWater_Offer;
   acknowledge 	= Mis_HolyWater_Acknowledge;
   refuse		= Mis_HolyWater_Refuse;
   abort		= Mis_HolyWater_Abort;
   done			= Mis_HolyWater_Done;
   running		= Mis_HolyWater_Running;
};

// ********************************************************************************************
//	Auftrags - Infos
// ********************************************************************************************

// ********************************************************************************************
//	Funktionen
// ********************************************************************************************
FUNC INT Mis_HolyWater_Conditions()
{
	RETURN 1;
};

FUNC INT Mis_HolyWater_Criteria()
{
	RETURN NpcHasItem(player, PsiPotion);
};

FUNC VOID Mis_HolyWater_Offer()
{
	AI_TurnToNpc(self, other);	
	AI_PlayAniSnd(self, "s_MissionOffer",	"",	"NSC: 'Hey, ich habe einen Auftrag für dich!'");
};

FUNC VOID Mis_HolyWater_Acknowledge()
{
	AI_TurnToNpc(self, other);	
	AI_PlayAniSnd(self, "s_MissionOffer",	"",	"NSC: 'Ich brauche dringend eine PSI-Phiole.'");
};

FUNC VOID Mis_HolyWater_Refuse()
{
	AI_TurnToNpc(self, other);	
	AI_PlayAniSnd(self, "s_InfoReject02",	"",	"NSC: 'Dummkopf, Du läßt Dir einen großen Schatz entgehen.'");
	Quit();
	AI_TurnAway(self, other);
};

FUNC VOID Mis_HolyWater_Abort()
{
	Mis_HolyWater_Refuse();
};

FUNC VOID Mis_HolyWater_Done(VAR INT ontime)
{
	GiveItem(other, Drug, self);

	IF (ontime==1)
	{
		AI_TurnToNpc(self, other);	
		AI_PlayAniSnd(self, "s_TradeAsk",	"",	"NSC: 'Gut gemacht, hier deine Belohnung.'");
	}
	ELSE
	{ 
		AI_TurnToNpc(self, other);	
		AI_PlayAniSnd(self, "s_TradeAsk",	"",	"NSC: 'Na endlich, du hast lange gebraucht. Hier deine Belohnung.'");
	};

	// die Belohnung
	CreateInvItem(player, RuneSword);
	other.exp += 10000;

	Quit();
};

FUNC VOID Mis_HolyWater_Running(VAR INT ontime)
{
	IF (ontime==1)
	{
		AI_TurnToNpc(self, other);	
		AI_PlayAniSnd(self, "s_TradeAsk",	"",	"NSC: 'Hast Du es dabei?'");
		Quit();
	}
	ELSE
	{ 
		AI_TurnToNpc(self, other);	
		AI_PlayAniSnd(self, "s_MissionFailed",	"",	"NSC: 'Du Versager, laß dich nicht mehr blicken, bevor alles erledigt ist!'");
		Quit();
	};
};

